Mainos / Advertisement:

RouterOS IPv6

Kohteesta Taisto
Siirry navigaatioon Siirry hakuun
Tämä sivu sisältää muutoksia, joita ei ole merkitty käännettäväksi.

Muut kielet:
suomi

RouterOS tukee myös IPv6 osoitteita. Sinun tulee ottaa käyttöön IPv6 ennen sen konfigurointia. Saat sen otettua käyttöön:

/system package enable ipv6

Käynnistä uudelleen

/system reboot

Native IPv6

Natiivinen IPv6 on yksinkertaista laittaa Mikrotikkiin. Lisää osoite vain IPv6 -> Address

 ipv6 address add="XXXXXXXXX" interface=ether1-gateway
 ipv6 address add="XXXXXXXXX" interface=bridge-local

ja lisäät sitten IPv6 routeen reitittimesi IP.

 ipv6 route add dst-address="XXXXXXX" prefix="XX" gateway="XXXXX"

6to4

6to4 on IPv6 tunneli jossa IPv6 on natiivina sisäverkossa ja reititetään tunnelissa IPv6 yhdyskäytävälle jossa jatkaa natiivina. Tätä käyttää operaattorit väliaikaisena siirtomenetelmänä IPv4 osoitteista IPv6 osoitteiksi.

Laske ensin IPv6-osoitteesi

Sinulla tulee olla staattinen IP osoite jotta tämä toimii. Tässä yksinkertainen laskin: http://silmor.de/ipaddrcalc.html (kuvassa alla esimerkki). Käytä omia IPv4-osoitteita.

 Staattinen IPv4-osoite: 194.137.109.179
 Staattinen IPv6-osoite: 2002:C289:6DB3::1
 Staattinen IPv6-osoite Pool: 2002:C289:6DB3::/48

RouterOS 6to4 1.png


Luo uusi interface 6to4.

/interface 6to4 add mtu=1480 name=sit1 local-address=194.137.109.178 remote-address=192.88.99.1 disabled=no

Lisää IP-osoitteet IPv6 interfaceen.

 /ipv6 address add address=2002:C289:6DB3::1/3 interface=sit1
 /ipv6 address add address=2002:C289:6DB3::2/48 interface=bridge-local

RouterOS 6to4 2.png

Tarkista reititys. Lisää Advertise bridge-local interfaceen, mainostaen tätä reitittimenä. IPv6 ei oletuksena määritetä DHCP palveluun reititintä-

 ip6 route print

RouterOS 6to4 3.png


Testaa pingailla IPv6-osoitteisiin

 ping 2001:4860:4860::8888

IPv6 nimelle ei voi pingata RouterOS käyttöjärjestelmässä.

6rd

Tässä alhaalla valmis scripti jolla saat toimimaan Soneran verkossa 6RD tunnelin Mikrotikillä.

Korvaa scriptissä LAN-INTERFACE ja WAN-INTERFACE omilla nimillä.

:global ipv6localinterface "LAN-INTERFACE"
:global uplinkinterface "WAN-INERFACE"
:global IPv4addr [/ip address get [find interface=$uplinkinterface] address];
:global IPv4addr [:pick $IPv4addr 0 [:find $IPv4addr "/"]]
:global IPv4addr2 [:pick $IPv4addr 4 30]
:global IPv6temp [:toip6 ("1::" . $IPv4addr)]
:global IPv4hex [:pick $IPv6temp 3 15]
:global IPv6addr [("2001:2003:". $IPv4hex .":00::1/56")]
:global IPv6addrLoc [("2001:2003:". $IPv4hex .":01::1/64")]

#6to4 interface
:global 6to4id [/interface 6to4 find where name="6rd"]
:if ($6to4id!="") do={
:global 6to4addr [/interface 6to4 get $6to4id local-address]
if ($6to4addr != $IPv4addr) do={ :log warning "Updating local-address for 6to4 tunnel '6rd' from '$6to4addr' to '$IPv4addr'."; /interface 6to4 set [find name="6rd"] local-address=$IPv4addr }
} else { :log warning "Creating 6to4 interface '6rd'. "; /interface 6to4 add !keepalive local-address=$IPv4addr mtu=1480 name="6rd" remote-address=80.221.111.254 }

#ipv6 for uplink
:global IPv6addrnumber [/ipv6 address find where comment="6rd" and interface="6rd"]
:if ($IPv6addrnumber!="") do={
:global oldip ([/ipv6 address get $IPv6addrnumber address])
if ($oldip != $IPv6addr) do={ :log warning "Updating 6rd IPv6 from '$oldip' to '$IPv6addr'."; /ipv6 address set number=$IPv6addrnumber address=$IPv6addr disabled=no }
} else {:log warning "Setting up 6rd IPv6 '$IPv6addr' to '6rd'. "; /ipv6 address add address=$IPv6addr interface="6rd" comment="6rd" advertise=no }

#ipv6 for local
:global IPv6addrnumberLocal [/ipv6 address find where comment=("6rd_local") and interface=$ipv6localinterface]
:if ($IPv6addrnumberLocal!="") do={
:global oldip ([/ipv6 address get $IPv6addrnumberLocal address])
if ($oldip != $IPv6addrLoc) do={ :log warning "Updating 6rd LOCAL IPv6 from '$oldip' to '$IPv6addrLoc'."; /ipv6 address set number=$IPv6addrnumberLocal address=$IPv6addrLoc disabled=no }
} else {:log warning "Setting up 6rd LOCAL IPv6 '$IPv6addrLoc' na '$ipv6localinterface'. "; /ipv6 address add address=$IPv6addrLoc interface=$ipv6localinterface comment="6rd_local" advertise=yes }

#ipv6 route
:global routa [/ipv6 route find where dst-address="2000::/3" and gateway="6rd"]
if ($routa="") do={ :log warning "Setting IPv6 route '2000::/3' pres '6rd'. "; /ipv6 route add distance=1 dst-address="2000::/3" gateway="6rd" }

Lähde: https://jani.malino.fi/sonera-6rd-ipv6-ja-mikrotikrouterboard/

Lähteet

http://www.mikrotik-routeros.com/2010/09/ipv6-and-mikrotik-using-6to4/

Mainos / Advertisement: